cmake_minimum_required(VERSION 3.21)
project(BrickSmash LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

if(NOT WIN32)
    message(FATAL_ERROR "이 예제는 STOVE PC SDK(x64 Windows 전용)를 사용하므로 Windows 에서만 빌드할 수 있습니다.")
endif()

# vcpkg manifest 모드로 설치되는 의존성
find_package(SDL3 CONFIG REQUIRED)
find_package(imgui CONFIG REQUIRED)

set(STOVE_SDK_DIR ${CMAKE_SOURCE_DIR}/third_party/StovePCSDK)
set(STOVE_VERIFIER_DIR ${CMAKE_SOURCE_DIR}/third_party/StoveSignatureVerifier)

add_executable(BrickSmash WIN32
    src/main.cpp
    src/StringUtil.cpp
    src/AppConfig.cpp
    src/stove/StoveSession.cpp
    src/stove/StoveGameSupport.cpp
    src/stove/StoveIAP.cpp
    src/game/Breakout.cpp
    src/ui/MenuScreen.cpp
    src/ui/GameScreen.cpp
    src/ui/ServiceScreens.cpp
    src/ui/RegulationOverlay.cpp
)

target_include_directories(BrickSmash PRIVATE
    ${CMAKE_SOURCE_DIR}/src
    ${STOVE_SDK_DIR}/Include
    ${STOVE_VERIFIER_DIR}/Include
)

target_link_libraries(BrickSmash PRIVATE
    SDL3::SDL3
    imgui::imgui
    ${STOVE_SDK_DIR}/lib/x64/BaseSDK.lib
    # 서명 검증 라이브러리는 릴리즈 구성에서만 링크한다.
    $<$<CONFIG:Release>:${STOVE_VERIFIER_DIR}/Lib/StoveSignatureVerifier_vs2022.lib>
)

if(TARGET SDL3::SDL3main)
    target_link_libraries(BrickSmash PRIVATE SDL3::SDL3main)
endif()

target_compile_options(BrickSmash PRIVATE /utf-8 /W3)
target_compile_definitions(BrickSmash PRIVATE UNICODE _UNICODE NOMINMAX WIN32_LEAN_AND_MEAN)

# 실행 파일 옆에 SDK DLL 과 설정 파일을 복사한다. (실제 ini 가 없으면 example 사용)
set(_cfg_src ${CMAKE_SOURCE_DIR}/config/stove_config.ini)
if(NOT EXISTS ${_cfg_src})
    set(_cfg_src ${CMAKE_SOURCE_DIR}/config/stove_config.example.ini)
endif()
add_custom_command(TARGET BrickSmash POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy_if_different
        ${STOVE_SDK_DIR}/dll/x64/BaseSDK.dll $<TARGET_FILE_DIR:BrickSmash>
    COMMAND ${CMAKE_COMMAND} -E make_directory $<TARGET_FILE_DIR:BrickSmash>/config
    COMMAND ${CMAKE_COMMAND} -E copy_if_different
        ${_cfg_src} $<TARGET_FILE_DIR:BrickSmash>/config/stove_config.ini
)
